Создание загрузочного ISO/DVD Windows Vista

Итак, вы подготовили установочные файлы Windows Vista, добавили к ним файл ответов и готовы записать все файлы на DVD-диск или создать его образ для последующего прожига. Для успешной установки Windows Vista с DVD-диска необходимо, чтобы он был загрузочным. В этой статье рассматривается создание загрузочного образа диска в формате ISO. Такой образ можно подключить к виртуальной машине для тестирования или прожечь на DVD-диск для использования в реальных условиях. Для создания ISO-образа будет использоваться утилита oscdimg.exe, которая входит в набор утилит командной строки Windows PE, устанавливаемых вместе с WAIK.

На этой странице

• Команда для создания ISO-образа
• Командный файл для создания ISO-образа
• Дальнейшие действия с ISO-образом

Команда для создания ISO-образа

Для создания образа требуется выполнить всего одну команду. Ее синтаксис зависит от разрядности операционной системы, образ которой вы создаете. Это связано с тем, что у 32- и 64-разрядной ОС разные загрузочные файлы. 

Например, для 32-разрядной ОС команда выглядит примерно так:

oscdimg -n -m -b"%programfiles%\Windows AIK\Tools\PETools\x86\boot\etfsboot.com" C:\VistaWork\DVD C:\VistaWork\ISO\Vista32.iso

Здесь используется утилита oscdimg.ехе, для которой задаются такие параметры:

• -n - включает поддержку длинных имен файлов.
• -m - игнорирует ограничение максимального размера образа.
• -b"%programfiles%\Windows AIK\Tools\PETools\x86\boot\etfsboot.com" - задает размещение загрузочного файла (пробелы не допускаются, поэтому путь заключен в кавычки). В общем случае параметр выглядит так: -b<путь к загрузочному файлу>. Между -b и путем также не должно быть пробелов.
• C:\VistaWork\DVD - путь к папке, содержащей установочные файлы.
• C:\VistaWork\ISO\Vistax86.iso - имя создаваемого ISO-образа и путь к нему.

Описание параметров командной строки для утилиты oscdimg.ехе на русском языке можно найти в документе "Параметры командной строки Oscdimg", который входит в состав справочного файла "Руководство пользователя по пакету автоматической установки Windows", поставляемого вместе с WAIK.
 

Вы можете адаптировать команду для своей ситуации или воспользоваться командным файлом, предлагаемым ниже.

Командный файл для создания ISO-образа

Содержимое командного файла приводится ниже. Подразумевается, что у вас установлен WAIK. Перед использованием файла необходимо задать в нем три параметра:

1. Путь к папке, содержащей установочные файлы.
2. Путь к папке, в которой будет сохранен ISO-образ.
3. Разрядность ОС, для которой создается образ (32 или 64).

:: Командный файл для создания ISO-образа Windows Vista
:: Размещен на OSZone.net

@echo off
:: Данные, которые необходимо ввести перед запуском файла

:: Укажите папку с установочными файлами Windows Vista
:: По умолчанию указана папка C:\VistaWork\DVD
SET source=C:\VistaWork\DVD
:: Укажите папку для сохранения ISO-образа
:: По умолчанию указана папка C:\VistaWork\ISO
SET target=C:\VistaWork\ISO
:: Укажите разрядность создаваемого дистрибутива
:: Задайте 32 или 64
:: По умолчанию создается образ 32-разрядной ОС
SET version=32


::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Проверка на предмет наличия установленного WAIK
:: и задание переменной %WAIK%
IF EXIST "%Programfiles%\Windows AIK\Tools\Servicing\pkgmgr.exe" SET WAIK=%Programfiles%\Windows AIK
IF NOT EXIST  "%Programfiles%\Windows AIK\Tools\Servicing\pkgmgr.exe" GOTO :NOWAIK

:CreateISO
:: Задание пути к файлу загрузчика
:: 32-разрядная версия
IF %version%==32 SET bootloader=%WAIK%\Tools\PETools\x86\boot\etfsboot.com
:: 64-разрядная версия
IF %version%==64 SET bootloader=%WAIK%\Tools\PETools\amd64\boot\etfsboot.com
:: Создание ISO-образа
"%WAIK%"\Tools\%PROCESSOR_ARCHITECTURE%\oscdimg.exe -n -m -b"%bootloader%" "%source%" "%target%\vista%version%.iso"
GOTO :Finish

:NOWAIK
SET WAIK=
ECHO WAIK не найден!
ECHO Укажите путь к папке с WAIK.
ECHO Например, введите E:\Software\Windows AIK
SET /P WAIK= Путь к WAIK:
CALL :CreateISO

:Finish
ECHO.
ECHO Создание ISO-образа завершено!
pause
exit

Внимание! Файл необходимо сохранять с расширением CMD в кодировке DOS-866. 

Если у вас не установлен WAIK, вы можете использовать этот набор файлов для создания ISO-образа. Начните с прочтения файла readme.txt.

Дальнейшие действия с ISO-образом

Вы можете подключить ISO-образ к виртуальной машине для дальнейшего тестирования (на виртуальной машине можно протестировать только образ 32-разрядной ОС). Например, в программе Microsoft Virtual PC для этого достаточно выбрать из меню CD пункт Capture ISO Image и выбрать образ.

Вы также можете прожечь ISO-образ на DVD-диск. Для цели подойдет любая программа, умеющая прожигать образы (к примеру, Small CD-Writer или Nero). Например, в программе Small CD-Writer достаточно в меню Диск выбрать пункт Записать ISO-образ на диск и выбрать образ.

Внимание! Не рекомендуется использование программ WinISO, UltraISO и аналогичных им для редактирования ISO-образа, т. к. существует риск повредить образ. Лучше произвести необходимые изменения в установочных файлах и создать образ заново.